Wi-Fi controlled RC car using ESP8266-01

#include <SoftwareSerial.h>


#define BACKWARDS 0
#define STOP 1
#define FORWARDS 2
#define LEFT 1
#define STRAIGHT 2
#define RIGHT 3


SoftwareSerial esp8266(2, 3); //Rx, Tx

/*
 * info will be our int array where we will keep
 * our commands for motors separately after splitting the command
 * variable into its digits.
 * info[0] will be our wheelDirection, info[1] our movement.
 */
int info[2] = {0}; 

/* This will keep the command coming from the ESP8266
 * Which for example could be numbers like 20, 11, 23
 */
int command;
char c;
int i;

void setup()
{
  Serial.begin(9600);  //For Serial monitor
  esp8266.begin(9600); //ESP Baud rate
  /*
     Don't make the mistake of using
     higher baud rates than the ESP8266 or Arduino UNO can handle
     like I did. Then you may get erroneous bits, hence erroneous commands.
  */

  // Pin outs for the front motor
  pinMode(13, OUTPUT);
  pinMode(12, OUTPUT);
  pinMode(9, OUTPUT);

  // Pin outs for the rear motor
  pinMode(7, OUTPUT);
  pinMode(6, OUTPUT);
  pinMode(5, OUTPUT);

  // Front motor output pins' initialization
  analogWrite(9, 0);
  digitalWrite(12, LOW);
  digitalWrite(13, HIGH);

  // Rear motor output pins' initialization
  digitalWrite(7, HIGH);
  digitalWrite(6, LOW);
  analogWrite(5, 0);
}

/* A function to split the command into its digits
 * and set the speed and direction of motors accordingly.
 */
void setSpeed(int newSpeed) {

  int temp = newSpeed;

  /* Printing out our command to the serial monitor so that
      we can check what's going on.
  */

  Serial.print("Command: ");
  Serial.println(temp);


  /* Here we are splitting the command (the number actually)
     into its digits. So that we can power the motors according
     to those digits and their meaning in switch case block.
  */
  i = 0;
  while (temp) {
    info[i] = temp % 10;
    temp /= 10;
    i++;
  }

  // Switch case block for front wheels.
  switch (info[1]) {
    case LEFT:
      analogWrite(9, 150);
      digitalWrite(12, HIGH);
      digitalWrite(13, LOW);
      break;
    case RIGHT:
      analogWrite(9, 150);
      digitalWrite(12, LOW);
      digitalWrite(13, HIGH);
      break;
    case STRAIGHT:
      analogWrite(9, 0);
      break;
  }

  // Switch case block for rear wheels.
  switch (info[0]) {
    case BACKWARDS:
      analogWrite(5, 150);
      digitalWrite(6, HIGH);
      digitalWrite(7, LOW);
      break;
    case FORWARDS:
      analogWrite(5, 150);
      digitalWrite(6, LOW);
      digitalWrite(7, HIGH);
      break;
    case STOP:
      analogWrite(5, 0);
      break;
  }
}

void loop()
{
  /* Here we are checking the number of bytes
   *  available for reading from the serial port.
   *  Then we read that data byte by byte checking
   *  if there is a colon ":". Because we are sending commands
   *  in a way like "command: 23" so that after a colon
   *  we can try to parse  to int what's in the buffer after ":".
   *  Which will parse just 2 numbers then stop.
   *  Then we call the setSpeed function.
   *  One last thing is that:
   *  We clear the buffer until there nothing to read at the end of each loop.
   */
  if (esp8266.available() > 0) {
    c = esp8266.read();
    if (c == ':') {
      command = esp8266.parseInt();
      setSpeed(command);
      while (esp8266.read() != -1) {
        //DO NOTHING - to clear the buffer.
      }
    }
  }
}

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <WebSocketsServer.h>

WebSocketsServer webSocket(81);

const char *ssid  = "softAPI";  // You will connect your phone to this Access Point
const char *pw    = "thereisnospoon"; // and this is the password

IPAddress ip(192, 168, 4, 1);
IPAddress netmask(255, 255, 255, 0);

void startWebSocket() { // Start a WebSocket server
  webSocket.begin(); // start the websocket server
  webSocket.onEvent(webSocketEvent); // if there's an incomming websocket message, go to function 'webSocketEvent'
  Serial.println("WebSocket server started.");
}

void webSocketEvent(uint8_t num, WStype_t type, uint8_t * payload, size_t lenght) { // When a WebSocket message is received
  switch (type) {
    case WStype_DISCONNECTED: // if the websocket is disconnected
      Serial.printf("[%u] Disconnected!\n", num);
      break;
    case WStype_CONNECTED: { // if a new websocket connection is established
        IPAddress ip = webSocket.remoteIP(num);
        if ( payload != NULL) {
          Serial.printf("[%u] Connected from %d.%d.%d.%d url: %s\n", num, ip[0], ip[1], ip[2], ip[3], payload);
        }
      }
      break;
    case WStype_TEXT: // if new text data is received,
      if (payload != NULL) {
        // I used an if statement here for the payload because when the payload was NULL, I was getting some weird errors from the ESP8266 and the device was resetting itself.
        Serial.printf("[%u] command: %s\n", num, payload);
      }
      break;
  }
}

void setup() {
  Serial.begin(9600);

  delay(1000);

  WiFi.softAPConfig(ip, ip, netmask);
  WiFi.mode(WIFI_AP);
  WiFi.softAP(ssid, pw); // configure ssid and password for softAP
  startWebSocket();
  Serial.printf("Soft AP created: %s", WiFi.softAPIP().toString().c_str());
}


void loop() {
  webSocket.loop();
}